hdctl -- мониторинг, управление и автоматизация с помощью ПК (софт для Windows)

import flash.utils.*;

var rrdgraph_cn_async:Function;
/**
 * rrdgraph_cn_async (conf_name:String, start:String, end:String, width:uint, height:uint, output_handler:Function, ...args) : void
 *
 * @param conf_name          имя [конфигурации] графика, из спиcка Graphs
 * @param start              начало отображаемого интервала времени, подробно о синтаксе в мануалах RRDTool
 * @param end                конец отображаемого интервала времени
 * @param width              ширина в пикселях
 * @param height             высота в пикселях
 * @param output_handler     обработчик результата, сюда выдаст бинарик PNG или ошибку
 * @param ...args            опциональные аргументы для передачи в output_handler
 */

function init()
{
  rrdgraph_cn_async = getDefinition('rrdtool.util::rrdgraph_cn_async') as Function;
  try {
    // построить график из конфигурации G1, за последних пять минут, 500*300 пикселей, 
    // бинарик выдать в методу graph_output, туда же вторым аргументом выдать время начала операции
    rrdgraph_cn_async('G1', -360, -1, 500, 300, graph_output, getTimer());
  } catch (error) {
    if (error.errorID == 1) print('нет такой конфигурации графика'); 
    if (error.errorID == 2) print('нет ни одного DS [с включенным логом] в конфигурации графика'); 
  }
  return 0;
}

private function graph_output(out, time)
{
  print('rrdgraph_cn_async done in ' + (getTimer() - time) + ' ms.');
  if (out is ByteArray) // картинка PNG бинарик 
  {
    print('size: ' + out.length + ' bytes.');
    print('head: ' + String(out).substr(0, 4));
    // далее делаем с бинариком что было задумано... 
  }
  else print(out); // out is Error (rrdgraph stderror output)
}

import flash.display.*;
import flash.events.*;
import flash.text.*;

var window, textfield, counter = 100, exit_flag;

function init()
{
  // получаем нужные классы из рантайма
  var NativeWindow = getDefinition('flash.display::NativeWindow');
  var NativeWindowInitOptions = getDefinition('flash.display::NativeWindowInitOptions');

  // создаем инстанцию окна
  window = new NativeWindow(new NativeWindowInitOptions);

  // подключаем обработчик события закрытия окна оператором
  window.addEventListener(Event.CLOSE, window_close);

  // задаем параметры окна
  window.width = 400; 
  window.height = 200; 
  window.title = 'Окошко'; 

  // задаем параметры корневого дисплей-объекта окна
  window.stage.align = StageAlign.TOP_LEFT;
  window.stage.scaleMode = StageScaleMode.NO_SCALE;

  // добавляем туда несколько цветных прямоугольников
  window.stage.addChild(new Bitmap(new BitmapData(100, 100, true, 0x8000ff00)));  
  window.stage.addChild(new Bitmap(new BitmapData(100, 100, true, 0x80ffff00))).x = 25;
  window.stage.addChild(new Bitmap(new BitmapData(200, 100, true, 0x8000ffff))).x = 75;

  // создаем, конфигурируем, и добавляем туда же динамическое текстовое поле
  textfield = new TextField;
  textfield.autoSize = TextFieldAutoSize.LEFT;
  textfield.defaultTextFormat = new TextFormat('_typewriter', 100);
  window.stage.addChild(textfield);

  window.activate();   // открываем окно

  return loop;
}

function loop ()
{
  textfield.text = --counter;
  return !exit_flag && counter ? loop : 0;
}

function window_close (event)
{
  exit_flag = true; // преждевременным закрытием окна завершим работу программы
}

// можно было бы закрыть окно сразу после завершения программы (exit),
// но мы закроем его вместе с консолью (close), если не было закрыто ранее оператором
//function exit (code) 
//{
//  window.close();
//}
function close ()
{
  window.removeEventListener(Event.CLOSE, window_close);
  window.close();
}

import flash.events.*;

var server, port = 5555, clients = [];

function init()
{
  // получаем класс из рантайма
  var ServerSocket = getDefinition('flash.net::ServerSocket');

  // создаем и запускаем сервера
  server = new ServerSocket;
  server.bind(port);
  server.listen();
  server.addEventListener(Event.CONNECT, client_connect);

  print(server + ' listening for incoming connections on TCP port ' + port);

  heartbeat = 1000;
  return loop;
}
function loop () 
{
  // генерируем данные
  var ts = new Date().time / 10000;
  var s = Math.sin(ts), c = Math.cos(ts), t = Math.tan(s - c);
  // посылаем отчет всем подключенным клиентам
  report (s.toFixed(3), c.toFixed(3), t.toFixed(3));

  return loop; // loop forever
}

function exit ()
{
  // отключаем всех клиентов
  for each (var client in clients) client.close();
  try {
    server.close(); // и останавливаем сервер
  } catch (error) { 
    print(error); 
  }
}

private function report (sin, cos, tan)
{
  for each (var client in clients)
  {
    client.writeUTFBytes('{SIN<' + sin + ' COS<' + cos + ' TAN<' + tan + '}');
    client.flush();
  }
}

private function client_connect (event)
{
  var client = event.socket;
  client.addEventListener(Event.CLOSE, client_close); 
  clients.push(client);
  print('open client connection ' + client_info(client));
}

private function client_close (event)
{
  var client = clients.splice(clients.indexOf(event.target), 1)[0];
  client.removeEventListener(Event.CLOSE, client_close);
  print('close client connection ' + client_info(client));
}

private function client_info (s) 
{
  return s.remoteAddress + ':' + s.remotePort + '->' + s.localAddress + ':' + s.localPort;
}